/* 2016.02.22
   4. SAS gyakorlat
   SZTE, Statisztika gyakorlati alkalmazasai */

/* Adatallomanyok rendezese */
proc sort data=work.szamla out=szamla2 ;
 by ugyfel_kod;
run;

proc sort data=work.ugyfel out=ugyfel2 ;
 by ugyfel_kod;
run;

/* adatallomanyok parositasa kozos, elozetesen rendezett kulcs alapjan */
data egyutt;
 merge szamla2 ugyfel2;
 by ugyfel_kod;
run;

/* csak azon esetek megtartasa, amelyekhez van szamla es ugyfel adat is */
data la16.egyutt;
 merge szamla2 (in=sz) 
       ugyfel2 (in=uf);
 by ugyfel_kod;
 if sz and uf;
run;

proc means data=la16.egyutt ;
run;

/* statisztikai tabla: 
   A nomenklaturakat (diszkret valtozo) a CLASS kulcsszoval vezetjuk be
*/
proc tabulate data=la16.egyutt ;
 class altipus devizanem_kod ;
 table altipus,
       devizanem_kod ;
run;

/* 3 diszkret valtozo szerinti elemszamok kiiratasa:
   3 dimenzios statisztikai tabla
*/
proc tabulate data=la16.egyutt ;
 class tipus altipus devizanem_kod ;
 table tipus,
       altipus,
       devizanem_kod ;
run;

/* Tabla csinositasa */
title "Tipusonként a különböző devizanemek gyakoriságai";
proc tabulate data=la16.egyutt ;
 class tipus altipus devizanem_kod ;
 table tipus="Típus",
       altipus="",
       devizanem_kod="" 
       / box="Altípus";
 keylabel n=" ";
run;


/* Folytonos valtozot (mutatot) is beveszunk a tablaba 
   es osszesennel (ALL) is szamolunk
*/
title "Tipusonként a különböző devizanemek összesen szerződéses összegei";
proc tabulate data=la16.egyutt ;
 class tipus altipus devizanem_kod ;
 var szerzodes_osszeg;
 table tipus="Típus",
       altipus="" all="Össz",
       devizanem_kod=""*szerzodes_osszeg all="Összesen"*szerzodes_osszeg
       / box="Altípus";
 keylabel n=" ";
run;