/* 2017.02.13
   2. gyakorlat - SAS
   SZTE, Statisztika gyakorlati alkalmazasai
*/

/* Excel kekszalag adatallomany megismerese S meghajtorol,
majd beolvasasa SAS-ba:
- Excel file feltoltese: Server files and folders \ upload
- Snippets \ data \ import xlsx --> datafile-hoz "" koze bemasolni
a feltoltott file nevet: Server files \ ... xlsx \ jobb egergomb: Properties \location
*/
PROC IMPORT DATAFILE="/home/laszlo.anna/a2/kekszalag2008_ere_jav2.xlsx"
		    OUT=la17.kek
		    DBMS=XLSX
		    REPLACE;
RUN;
PROC PRINT DATA=la17.kek; RUN;

/* Adatallomany jellemzoi:
ebbol kiderul, hogy 1338 soros az adatallomany, es 66 valtozoja van
*/
proc contents data=la17.kek; run;

/* kekjo nevu adatallomanyba a 7 fontos valtozo megtartasa (keep)
es csak az elso 524 sor (lenyegi adatok) meghagyasa
Futtatas utan a LOG-ban note:
"NOTE: The data set LA17.KEKJO has 524 observations and 7 variables."
*/
data la17.kekjo (keep = sorren kateg hajonev ys befut futott korrig);
 set la17.kek;
 if _N_ le 524 then output;
run;

/* leiro statisztika a numerikus adatokra */
proc means data=la17.kekjo;
run;

/* tobb leiro statisztika (ferdeseg, csucsossag, kiugro ertekek), 
hisztogram is keszitheto */
proc univariate data=la17.kekjo;
 histogram;
run;
/* csak adott valtozora futtatva a hisztogramot */
proc univariate data=la17.kekjo;
 histogram ys;
run;

/* csoportonkenti gyakorisagok szamlalasa
Elotte rendezni kell az adott csoportosito valtozo szerint az adatallomanyt.
Kulon allomanyba erdemes kimenteni a rendezett adatokat (out=), 
 hogy ne irjuk felul az eredetit (ha nem szeretnenk)
*/
proc sort data=la17.kekjo out=rendezett;
 by kateg;
run;
proc freq data=rendezett;
 tables kateg / out=gy;
run;
/* gyakorisagi oszlopdiagram */
proc gchart data=gy;
   vbar kateg / sumvar=count ;
run;
quit; 

/* linearis korrelacio: Pearson */
title 'Hajó korrelációja';
proc corr data=la17.kekjo;
run;

/* Sorrend felvetele */
proc sort data=la17.kekjo out=rend2;
 by futott;
run;
data la17.kekjobb;
 set rend2;
 sorrend = _N_ ;
run;
proc corr data=la17.kekjobb;
run;